म्यूजिक एक थेरेपी की तरह हमारे शरीर के लिए काम करता है, लेकिन अक्सर हम कंफ्यूज से रहते है की हम कौन सा म्यूजिक सुनें, ऐसे में सबसे बढ़िया ऑप्शन होता है रेडियो, जो हमे हर तरह का म्यूजिक एन्जॉय करने में हमारी मदद करता है, तो इस आर्टिकल में मैं आपको एक ऐसी कोडिंग दे रहा हूँ जिसकी मदद से आप अपना खुदका रेडियो अपने कंप्यूटर में बना सकते है और जब चाहे इसे इंटरनेट चालू करके चला सकते है, इसके लिए आपको किसी तरह के सॉफ्टवेयर की जरुरत नहीं होगी न ही आपको ब्राउज़र ओपन करने की जरुरत है, सिर्फ अपने कंप्यूटर के नोटपैड से ही आप ये रेडियो बड़ी आसानी से बना सकते है, इसके लिए आपको सिर्फ नीचे दी गई कोड को कॉपी करना है और जैसा वीडियो में बताया गया है उन स्टेप्स को फॉलो करना है और फिर क्या एन्जॉय करिये दुनिया के अलग अलग गानो का।
--------------------------------------------------------------------------------------------------------------
@echo off & Title Playing Some Radios Stations
REM First we create a Shortcut with a Hotkey "CTRL+R" by calling this sub like this way :
REM CreateShortcut <ApplicationPath> <ShortcutName> <Icon> <HotKey>
Call :CreateShortcut "%~f0" "Radios Stations" "%Windir%\System32\SHELL32.dll,138" "CTRL+R"
:menuLOOP
Title Playing Some Radios Stations
Color 9E & Mode 80,18
::===========================================================================
echo(
echo(
echo( ***************************** Menu ******************************
echo(
@for /f "tokens=2* delims=_ " %%A in ('"findstr /b /c:":menu_" "%~f0""') do (
echo( %%A %%B)
echo(
echo( *****************************************************************
echo( &Set /p Selection=Make a Selection or hit ENTER to quit: ||Goto :EOF
echo( & Call:menu_[%Selection%]
GOTO:menuLOOP
::===========================================================================
:menu_[1] Play DJ Buzz Radio Station
Call :StopMusic
Set "Music_URL=https://stream.initialradio.fr:8443/djbuzz-192k.mp3"
Call :Play "%Music_URL%" "Playing DJ Buzz Radio Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[2] Play RetroDance Radio Station
Call :StopMusic
Set "Music_URL=http://retro.dancewave.online/retrodance.mp3"
Call :Play "%Music_URL%" "Play RetroDance Radio Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[3] Play Radio Mosaique DJ Station
Call :StopMusic
Set "Music_URL=http://radio.mosaiquefm.net:8000/mosadj"
Call :Play "%Music_URL%" "Playing Radio Mosaique DJ Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[4] Play Radio Mosaique GOLD Station
Call :StopMusic
Set "Music_URL=http://radio.mosaiquefm.net:8000/mosagold"
Call :Play "%Music_URL%" "Playing Radio Mosaique GOLD Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[5] Play Radio 100% HIT JFM Station
Call :StopMusic
Set "Music_URL=http://streaming2.toutech.net:8000/jfmweb4"
Call :Play "%Music_URL%" "Playing Radio 100%%%% HIT JFM Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[6] Play Radio 100% GOLD JFM Station
Call :StopMusic
Set "Music_URL=http://streaming2.toutech.net:8000/jfmweb2"
Call :Play "%Music_URL%" "Playing Radio 100%%%% GOLD JFM Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[7] Play Radio 100% CLUBBING JFM Station
Call :StopMusic
Set "Music_URL=http://streaming2.toutech.net:8000/jfmweb3"
Call :Play "%Music_URL%" "Playing Radio 100%%%% CLUBBING JFM Station"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[8] Play Generation Dance Radio
Call :StopMusic
Set "Music_URL=http://generationdance.lu:8010/hd"
Call :Play "%Music_URL%" "Playing Generation Dance Radio"
Goto:menuLoop
::---------------------------------------------------------------------------
:menu_[9] Stop Stremaing Radio station
Call :StopMusic
Goto:menuLoop
::---------------------------------------------------------------------------
:Play <URL> <Title>
(
echo Play "%~1"
echo Sub Play(URL^)
echo Dim Sound
echo Set Sound = CreateObject("WMPlayer.OCX"^)
echo Sound.URL = URL
echo Sound.settings.volume = 100
echo Sound.Controls.play
echo While Sound.playState ^<^> 1
echo wscript.sleep 100
echo Wend
echo End Sub
)>"%Temp%\PlayMusic.vbs"
start "%~2" /Min cscript.exe //nologo "%Temp%\PlayMusic.vbs"
exit /b
::-----------------------------------------------------------------------------
:StopMusic
Taskkill /IM "cscript.exe" /F >Nul 2>&1
Exit /B
::-----------------------------------------------------------------------------
:CreateShortcut <ApplicationPath> <ShortcutName> <Icon> <HotKey>
(
echo Call Shortcut("%~1","%~2","%~3","%~4"^)
echo Sub Shortcut(ApplicationPath,Name,Icon,HotKey^)
echo Dim objShell,DesktopPath,objShortCut,MyTab
echo Set objShell = CreateObject("WScript.Shell"^)
echo MyTab = Split^(ApplicationPath,"\"^)
echo If Name = "" Then
echo Name = MyTab(UBound^(MyTab^)^)
echo End if
echo DesktopPath = objShell.SpecialFolders("Desktop"^)
echo Set objShortCut = objShell.CreateShortcut(DesktopPath ^& "\" ^& Name ^& ".lnk"^)
echo objShortCut.TargetPath = Chr(34^) ^& ApplicationPath ^& Chr^(34^)
echo ObjShortCut.IconLocation = Icon
echo ObjShortCut.WorkingDirectory = "%~dp0"
echo objShortCut.HotKey = Hotkey
echo objShortCut.Save
echo End Sub
)>"%temp%\Shortcutme.vbs"
wscript "%temp%\Shortcutme.vbs" & Del "%temp%\Shortcutme.vbs"
Exit /b
::------------------------------------------------------------------------------
Download Above Script in Notepad File:
Follow the Steps from Video:
0 टिप्पणियाँ